在低版本Forge中玩转FG5！

buildscript {
    ext.kotlin_version = '1.7.20'   // kotli 版本
    repositories {
        mavenLocal()
        maven { url = "https://maven.aliyun.com/repository/public" }    // 阿里云镜像
        mavenCentral()
        // These repositories are only for Gradle plugins, put any other repositories in the repository block further below
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath 'org.spongepowered:mixingradle:0.7.+'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}
// Only edit below this line, the above code adds and enables the necessary things for Forge to be setup.
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'kotlin'
apply plugin: 'org.spongepowered.mixin'

version = '1.0'
group = '' // http://maven.apache.org/guides/mini/guide-naming-conventions.html

sourceCompatibility = targetCompatibility = '1.8'

minecraft {
    mappings channel: 'snapshot', version: '20171003-1.12'
    runs {
        client {
            workingDirectory project.file('run')

            // Recommended logging data for a userdev environment
            // The markers can be added/remove as needed separated by commas.
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            property 'forge.logging.markers', 'REGISTRIES'

            // Recommended logging level for the console
            // You can set various levels here.
            // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
            property 'forge.logging.console.level', 'debug'

            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            property 'forge.enabledGameTestNamespaces', 'mi'
        }

        server {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'

            property 'forge.logging.console.level', 'debug'

            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            property 'forge.enabledGameTestNamespaces', 'mi'
        }
    }
}

repositories {
    mavenCentral()
    // Put repositories for dependencies here
    // ForgeGradle automatically adds the Forge maven and Maven Central for you

    // If you have mod jar dependencies in ./libs, you can declare them as a repository like so:
    // flatDir {
    //     dir 'libs'
    // }
}

dependencies {
    minecraft 'net.minecraftforge:forge:1.12.2-14.23.5.2859'
    implementation 'org.spongepowered:mixin:0.8.5'
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

mixin {
    // MixinGradle Settings
    add sourceSets.main, 'mixins.mi.refmap.json'
    config 'mixins.mi.json'
}

// Example for how to get properties into the manifest for reading at runtime.
jar {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    from {
        // 将 mixin 和 kotlin 打包到 jar 中
        configurations.runtimeClasspath.findAll {
            it.name.contains("mixin") || it.name.contains("kotlin")
        }.collect {
            zipTree(it)
        }
    } {
        // 排除一些文件
        exclude '**/module-info.class',
                'LICENSE.txt',
                'META-INF/MUMFREY.RSA',
                '**/*.kotlin_module'
    }
}

compileJava {
    options.encoding 'UTF-8'
    sourceCompatibility '1.8'
    targetCompatibility '1.8'
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}